Créer un indicateur « BOX » session asiatique

Bonjour à tous,

Voici une demande de codage, en apparence simple,  mais pas tant que cela…

Il s’agit de créer un indicateur qui visuellement affiche un rectangle correspondant à la session asiatique (00H à 08H).
Ainsi que 2 rectangles au-dessus et en-dessous, à distance de 25 et 50 pips.

J’ai trouvé cette demande intéressante, car bizarrement j’ai eu 3 fois la même demande ce mois-ci (la loi des séries ?), et de plus ProRealTime permet désormais le tracé de figures : rectangles, ellipses, flèches…

On peut même positionner du texte à la demande, faire des lignes, des figures, etc.

 

 

 

 

Voici de code de l’INDICATEUR « Background Color » :

IF time > 000000 and time <= 080000 THEN
backgroundcolor(30,30,255)
ENDIF

RETURN

 

Voici de code complet de l’INDICATEUR « BOX session asiatique » + les 2 autres boîtes de chaque coté :

// heures de session
debut = 010000
fin = 080000

// TRACE DU RECTANGLE DE SESSION ASIATIQUE

IF time = debut THEN
haut = 0
bas = 0
barredebut = barindex
ENDIF

IF time = fin THEN
barrefin = barindex
ENDIF

IF time >= debut AND time <= fin THEN
IF high > haut THEN
haut = high
ENDIF
IF low < bas OR time = debut THEN
bas = low
ENDIF
ENDIF
 
IF time >= fin THEN
DRAWRECTANGLE(barredebut,haut,barrefin,bas) coloured(30,30,255)
ENDIF

// TRACE DES 2 RECTANGLES AU-DESSUS & EN-DESSOUS
hauteur1 = 25 * pipsize
hauteur2 = 50 * pipsize

IF time >= fin THEN
DRAWRECTANGLE(barredebut,haut+hauteur1,barrefin,haut+hauteur2) coloured(150,150,150)
ENDIF

IF time >= fin THEN
DRAWRECTANGLE(barredebut,bas-hauteur1,barrefin,bas-hauteur2) coloured(150,150,150)
ENDIF

RETURN

 

 

 

Share Button